particles

1 files changed, 0 insertions, 71 deletions

diff --git a/src/shader/shader.wgsl b/src/shader/shader.wgsl
deleted file mode 100644
index fb1e0b1..0000000
--- a/src/shader/shader.wgsl
+++ /dev/null
@@ -1,71 +0,0 @@
-struct Camera {
-    scale: vec2f,
-    centre: vec2f,
-};
-
-struct Instance {
-    centre: vec2f,
-    cos_sin: vec2f,
-    half_size: vec2f,
-    dims: vec2u,
-    cell_offset: u32,
-};
-
-@group(0) @binding(0) var<uniform> camera: Camera;
-@group(0) @binding(1) var<storage, read> palette: array<vec4f>;
-@group(0) @binding(2) var<storage, read> instances: array<Instance>;
-@group(0) @binding(3) var<storage, read> cells: array<u32>;
-
-struct VertexOutput {
-    @builtin(position) clip_position: vec4<f32>,
-    @location(0) world: vec2<f32>,
-    @location(1) @interpolate(flat) instance: u32,
-};
-
-@vertex
-fn vs_main(
-    @builtin(vertex_index) i: u32,
-    @builtin(instance_index) n: u32,
-) -> VertexOutput {
-    let instance = instances[n];
-
-    // (-1,-1),(1,-1),(-1,1),(1,1)
-    let corner = vec2f(f32(i & 1u), f32(i >> 1u)) * 2.0 - 1.0;
-    let local = corner * (instance.half_size + 2.0);
-    let world = instance.centre + vec2f(
-        local.x * instance.cos_sin.x - local.y * instance.cos_sin.y,
-        local.x * instance.cos_sin.y + local.y * instance.cos_sin.x,
-    );
-
-    var out: VertexOutput;
-    out.clip_position = vec4f((world - camera.centre) * camera.scale, 0.0, 1.0);
-    out.world = world;
-    out.instance = n;
-
-    return out;
-}
-
-@fragment
-fn fs_main(in: VertexOutput) -> @location(0) vec4<f32> {
-    let instance = instances[in.instance];
-
-    let d = in.world - instance.centre;
-    let q = floor(d) + vec2f(0.5);
-    let local = vec2f(
-        q.x * instance.cos_sin.x + q.y * instance.cos_sin.y,
-        -q.x * instance.cos_sin.y + q.y * instance.cos_sin.x,
-    ) + instance.half_size;
-
-    let cell = vec2i(floor(local));
-    if any(cell < vec2i(0)) || any(cell >= vec2i(instance.dims)) {
-        discard;
-    }
-
-    let idx = instance.cell_offset + u32(cell.y) * instance.dims.x + u32(cell.x);
-    let material = (cells[idx >> 2u] >> ((idx & 3u) * 8u)) & 0xFFu;
-    if material == 0u {
-        discard;
-    }
-
-    return palette[material];
-}